DEMO   ENGLISH   CONFIG (1.0)
  ROOTCAT   S.
  FILES  .
  LEXENTRIES   (DEMO ENGLISH).
  TEMPLATES (DEMO ENGLISH). 
  RULES   (DEMO ENGLISH).
  GOVERNABLERELATIONS    SUBJ OBJ OBJ2 COMP XCOMP OBL OBL-?+.
  SEMANTICFUNCTIONS    ADJUNCT  TOPIC FOCUS POSS STANDARD.
  NONDISTRIBUTIVES    NUM PERS CONJ-FORM.
  EPSILON   e.
OPTIMALITYORDER NOGOOD.

----

DEMO   ENGLISH   RULES (1.0)

   S --> NP: (^ SUBJ)=!
	     (! CASE)=NOM;
 	 VP: ^=!.

   VP --> V: ^=!; 
 	  (NP: (^ OBJ)=!
	       (! CASE)=ACC).

   NP --> (D)
 	  N. 

----
DEMO   ENGLISH   TEMPLATES (1.0)

   OPT-TRANS(P) = { (^ PRED) = 'P<(^SUBJ)(^OBJ)>'   "P is a variable"
	  | (^ PRED) = 'P<(^SUBJ)>' }.  "this template takes one argument:  P"
	  
   VPRES = @(TENSE pres) 
	   @(MOOD indicative). 

   TENSE(T) = (^ TENSE) = T.  "the more general case"

   "TENSE = (^ TENSE) = pres."  "not such a good option"

   MOOD(M) = (^ MOOD) = M.

----

DEMO ENGLISH LEXICON (1.0)

bones 	  N * (^ PRED) = 'bone'
	      (^ NUM) = pl
	      (^ PERS) = 3. 

homework  N * (^ PRED) = 'homework'
	      (^ NUM) = sg
	      (^ PERS) = 3. 

dog 	  N * (^ PRED) = 'dog'
	      (^ NUM) = sg
	      (^ PERS) = 3. 

dogs 	  N * (^ PRED) = 'dog'
	      (^ NUM) = pl
	      (^ PERS) = 3. 

ate 	  V * @(OPT-TRANS eat)  "template for optionally transitive verbs"
	      (^ TENSE) = past
	      (^ MOOD) = indicative.

eats 	  V * @(OPT-TRANS eat)
	      @VPRES. 

drinks   V * @(OPT-TRANS drink)
             @VPRES. 

devoured  V * (^ PRED) = 'devour<(^SUBJ)(^OBJ)>' 
	      (^ TENSE) = past
	      (^ MOOD) = indicative.

sleeps   V *  (^ PRED) = 'sleep<(^SUBJ)>' 
       	    (^ TENSE) = pres
	    (^ MOOD) = indicative
            (^ SUBJ PERS) = 3 
            (^ SUBJ NUM) = sg.

sleep 	  V * (^ PRED) = 'sleep<(^SUBJ)>' 
	      (^ TENSE) = pres
	      (^ MOOD) = indicative
	      { (^ SUBJ NUM) = pl "either it is plural"
	      | (^ SUBJ PERS) ~= 3 "or it is singular and not 3rd person"
		(^ SUBJ NUM) = sg}.

the  D *  (^DEF) = +.

a  D *  (^DEF) = -
        (^ NUM) = sg.

----