TOY    ENGLISH   CONFIG (1.0)
  ROOTCAT   S.
  FILES  .
  LEXENTRIES   (TOY ENGLISH).
  TEMPLATES   (TOY ENGLISH).
  RULES   (TOY ENGLISH).
  GOVERNABLERELATIONS    SUBJ OBJ OBJ2 OBJ-TH OBL OBL-?+ COMP XCOMP.
  SEMANTICFUNCTIONS    ADJUNCT  TOPIC.
  NONDISTRIBUTIVES    NUM PERS COORD-FORM COORD-TYPE STMT-TYPE.
  EPSILON   e.

----

TOY ENGLISH RULES (1.0)

   S --> NP: (^ SUBJ) = !;
 	 VP: ^ = !;
 	 (PERIOD).

   VP --> (AUX)
 	  V: ^ = !;
 	  ({ NP: (^ OBJ) = !
		 (! CASE) = acc
 	    |NP: (^ OBJ) = !
		 (! CASE) = acc;
 	     NP: (^ OBJ-TH) = !
		 (! CASE) = dat})
 	  PP*: { (^ OBL) = !
		|! $ (^ ADJUNCT)}.

   NP --> { { (DET: (^ SPEC DET) = !)
 	     |(POSS: (^ SPEC POSS) = !)}
 	    AP*: ! $ (^ ADJUNCT);
 	    N: ^ = !
 	  | PRON: ^ = !}
 	  PP*: ! $ (^ ADJUNCT).

   PP --> P: ^ = !;
 	  NP: { (^ OBJ) = !
	      | ^ = !}.

   AP --> A: ^ = !.

----

TOY ENGLISH TEMPLATES (1.0)

   V3SG = "3rd person singular verb"
	  (^ SUBJ NUM) =c sg
	  (^ SUBJ PERS) =c 3.

   NONV3SG = "non-3rd person singular verb"
	  { (^ SUBJ NUM) =c pl
	   |(^ SUBJ NUM) =c sg
	    (^ SUBJ PERS) ~= 3
	   |(^ TENSE) =c future}.

   NSG(P) = "singular noun"
	  (^ PRED) = 'P'
	  (^ PERS) = 3
	  (^ NUM) = sg.

   NPL(P) = "plural noun"
	  (^ PRED) = 'P'
	  (^ PERS) = 3
	  (^ NUM) = pl.

   TRANS(P) = "transitive verb"
	  @(PASS (^ PRED) = 'P<(^ SUBJ)(^ OBJ)>').

   INTRANS(P) = "intransitive verb"
	  (^ PRED) = 'P<(^ SUBJ)>'.

   DITRANS(P) = "ditransitive verb"
	 @(DAT-SHIFT (^ PRED) = 'P<(^ SUBJ)(^ OBJ)(^ OBL)>').

   OPTTRANS(P) = "intransitive or transitive verb"
	  { @(TRANS P)
	   |@(INTRANS P)}.

   PRES = "present tense"
	  (^ TENSE) = present.

   PRESFUT = "present or future tense"
	  { (^ TENSE) = present
	   |(^ TENSE) =c future}.

   PAST = "past tense"
	  (^ TENSE) = past.

   PERSPRON(P PERSON NUMBER) = "personal pronoun" 
	  (^ PRED) = 'P'
	  (^ PERS) = PERSON
	  (^ NUM) = NUMBER.

   POSSPRON(P PERSON NUMBER) = "possessive pronoun" 
	  (^ PRED) = 'P'
	  (^ PERS) = PERSON
	  (^ NUM) = NUMBER
	  (^ PRON-TYPE) = poss.

   PREPSEM(P) = "semantic preposition"
	  (^ PRED) = 'P<(^ OBJ)>'.

   PREPNOSEM(P) = "nonsemantic preposition"
	  (^ PCASE) = P.

   ADJ(P) = "adjectives"
	  (^ PRED) = 'P'.

   PASS(SCHEMATA) = "lexical rule for passive"
	  { SCHEMATA
	   |SCHEMATA
	    (^ PASSIVE) =c +
	    (^ OBJ) --> (^ SUBJ)
	    { (^ SUBJ) --> (^ OBL-AG)
	     |(^ SUBJ) --> NULL}}.

   DAT-SHIFT(SCHEMATA) = "lexical rule for dative shift"
	  { SCHEMATA
	    (^ OBL PCASE) =c to
	   |SCHEMATA
	    (^ OBJ) --> (^ OBJ-TH)
	    (^ OBL) --> (^ OBJ)}.

----

TOY ENGLISH LEXICON (1.0)

students  N * @(NPL student).

student   N * @(NSG student).
	   
Pete 	  N * @(NSG Pete).

dog 	  N * @(NSG dog).

monkey 	  N * @(NSG monkey).

children  N * @(NPL child).

room	  N * @(NSG room).

bone	  N * @(NSG bone).

coin	  N * @(NSG coin).

kill 	  V * @(TRANS kill)
	      @NONV3SG
	      @PRESFUT.

kills 	  V * @(TRANS kill)
	      @V3SG
	      @PRES.

killed 	  V * @(TRANS kill)
	      @PAST.
 
see 	  V * @(TRANS see)
	      @NONV3SG
	      @PRESFUT.

sees 	  V * @(TRANS see)
	      @V3SG
	      @PRES.

sleep 	  V * @(INTRANS sleep)
	      @NONV3SG
	      @PRESFUT.

sleeps 	  V * @(INTRANS sleep)
	      @V3SG
	      @PRES.

slept 	  V * @(INTRANS sleep)
	      @PRES.

waits 	  V * @(INTRANS wait)
	      @V3SG
	      @PRES.

played 	  V * @(OPTTRANS play)
	      @PAST.

stinks 	  V * @(INTRANS stink)
	      @V3SG
	      @PRES.

rain 	  V * (^ PRED) = 'rain<>(^ SUBJ)'
	      @NONV3SG
	      @PRESFUT
	      (^ SUBJ PRON-FORM) =c it.

seen 	  V * @(TRANS see)
	      @PAST.

give 	  V * @(DITRANS give)
	      @NONV3SG
	      @PRESFUT.

gives 	  V * @(DITRANS give)
	      @V3SG
	      @PRES.

given 	  V * @(DITRANS give)
	      @PAST.

will 	  AUX * (^ TENSE) = future.

have 	  AUX * (^ TENSE) = past.

was 	  AUX * (^ TENSE) = past
		(^ PASSIVE) = +.

a 	  DET * (^ DEF) = -.

the 	  DET * (^ DET) = +.	      
	      
 . 	  PERIOD * .

I	  PRON * @(PERSPRON I 1 sg).

you 	  PRON * { @(PERSPRON you 2 sg)
		  |@(PERSPRON you 2 pl)}.

he 	  PRON * @(PERSPRON he 3 sg)
		 (^ GEND) = masc.

she	  PRON * @(PERSPRON she 3 sg)
		 (^ GEND) = fem.

it 	  PRON * { @(PERSPRON it 3 sg)
		   (^ GEND) = neut
		  |(^ PRON-FORM) = it}.

we	  PRON * @(PERSPRON we 1 pl).

they	  PRON * @(PERSPRON they 3 pl).

my	  POSS * @(POSSPRON I 1 sg).

your 	  POSS * { @(POSSPRON you 2 sg)
		  |@(POSSPRON you 2 pl)}.

his	  POSS * @(POSSPRON he 3 sg)
		 (^ GEND) = masc.

her	  POSS * @(POSSPRON she 3 sg)
		 (^ GEND) = fem.

its	  POSS * @(POSSPRON it 3 sg)
		 (^ GEND) = neut.

our	  POSS * @(POSSPRON we 1 pl).

their	  POSS * @(POSSPRON they 3 pl).

in	  P * @(PREPSEM in).

with	  P * @(PREPSEM with).

to	  P * @(PREPNOSEM to).

by 	  P * @(PREPNOSEM by).

small 	  A * @(ADJ small).

big 	  A * @(ADJ big).

----